www.Agilent-Tech.comProductsServices & Supportwww.HP.com
Agilent-Technologies LogoSemiconductor Products
Search
Assistance
SPG home
 HPRFhelp home
 Design Info
  models

 SPICE models
  Schottkys
  PINs
  BJTs
  FETs
  MSAs
  INAs
  IAMs
  AT packages
  MSA packages
  INA packages
 MDS models
 ADS models
 Equivalent Ckts

 What's New
 How to Buy
 
SPICE Library: AT and HBFP Series Models

  Models are available for the following devices:


AT-305 Model

[ top ]
SPICE model

** DIE MODEL (excludes bond wires)
.SUBCKT AT305   75      20      85
CBBP    20      75      .03PF
CEBP    85      75      .03PF
QINT    75      20      85      Q305     
.ENDS

.MODEL  Q305    NPN (BF=100, BR=2.5, IS=7.8E-17, VA=20, TF=12PS, 
+               CJE=1.1E-13, VJE=1.01, MJE=0.6, PTF=25, XTB=1.818,
+               VTF=6, ITF=1.4E-2, IKF=6.3E-3, XTF=4, NF=1.03, ISE=2.4E-13,
+               NE=2.5, RB=38.49, RE=2.44, RC=61.57, CJC=5.1E-14, CJS=7E-14,
+               XCJC=0.19, PS=0.8, MS=0.5, PC=0.76, MC=0.53)
To complete the transistor model, the above die model must be combined with one of the following package models.

AT-30511
pkg dwg
package 11 model
AT-30533
pkg dwg
package 33 model


AT-310 Model

[ top ]
SPICE model

* DIE MODEL (excludes bond wires)
.SUBCKT AT310   75      20      85
CBBP    20      75      .03PF
CEBP    85      75      .03PF
QINT    75      20      85      Q310     
.ENDS

.MODEL  Q310    NPN (BF=100, BR=2.5, IS=1.6E-16, VA=20, TF=12PS, 
+               CJE=2.3E-13, VJE=1.01, MJE=0.6, PTF=25, XTB=1.818,
+               VTF=6, ITF=2.9E-2, IKF=1.3E-2, XTF=4, NF=1.03, ISE=4.8E-13,
+               NE=2.5, RB=19.44, RE=1.22, RC=40.68, CJC=9.5E-14, CJS=1E-13,
+               XCJC=0.20, PS=0.8, MS=0.5, PC=0.76, MC=0.53)
To complete the transistor model, the above die model must be combined with one of the following package models.

AT-31011
pkg dwg
package 11 model
AT-31033
pkg dwg
package 33 model


AT-320 model

[ top ]
SPICE model

* DIE MODEL (excludes bond wires)
.SUBCKT AT320   75      20      85
CBBP    20      75      .03PF; BASE BOND PAD CAPACITANCE
CEBP    85      75      .03PF; EMITTER BOND PAD CAPACITANCE
QINT    75      20      85      Q320     
.ENDS

.MODEL  Q320    NPN (BF=100, BR=2.5, IS=3.1E-16, VA=20, TF=12PS, 
+               CJE=4.6E-13, VJE=1.01, MJE=0.6, PTF=25, XTB=1.818,
+               VTF=6, ITF=5.7E-2, IKF=2.5E-2, XTF=4, NF=1.03, ISE=9.5E-13,
+               NE=2.5, RB=9.78, RE=0.61, RC=35.97, CJC=1.8E-13, CJS=1.7E-13,
+               XCJC=0.20, PS=0.8, MS=0.5, PC=0.76, MC=0.53)
To complete the transistor model, the above die model must be combined with one of the following package models.

AT-32011
pkg dwg
package 11 model
AT-32033
pkg dwg
package 33 model
AT-32086
pkg dwg
package 63 model


AT-414 Model

[ top ]
SPICE model

* DIE MODEL (excludes bond wires)
.SUBCKT AT414   75      20      85
CCB     20      60      .032PF
DCD1    20      60      DMOD    572
RRB1    20      25      1.07    TC=0.8E-3
DCD2    25      60      DMOD    680
RRB2    25      30      3.2     TC=1.2E-3
DCD3    30      60      DMOD    340
RRB3    30      35      2.7     TC=1.8E-3
RRC     60      75      5       TC=0.6E-3
RRE     80      85      .24     TC=0.6E-3
CCE     60      85      .032PF
QINT    60      35      80      QDIS     420
.ENDS

.MODEL  DMOD    D(IS=1E-25, CJO=2.45E-16, VJ=.76, M=.53, BV=45, IBV=1E-9)
.MODEL  QDIS    NPN (BF=100, BR=2.5, IS=1.65E-18, VA=20, TF=12PS,
+               CJE=2.4E-15, VJE=1.01, MJE=0.6, PTF=25, XTB=1.818,
+               VTF=6, ITF=3E-4, IKF=1.3E-4, XTF=4, NF=1.03, ISE=5E-15,
+               NE=2.5)
To complete the transistor model, the above die model must be combined with one of the following package models.

AT-41400
pkg dwg
package 00 model
AT-41410
pkg dwg
package 10 model
AT-41411
pkg dwg
package 11 model
AT-41435
pkg dwg
package 35 model
AT-41470
pkg dwg
package 70 model
AT-41485
pkg dwg
package 85 model
AT-41486
pkg dwg
package 86 model


AT-415 Model

[ top ]
SPICE model

* DIE MODEL (excludes bond wires)
.SUBCKT AT415   75      20      85
CBBP    20      75      .064PF;  BASE BOND PAD CAPACITANCE
CEBP    85      75      .064PF;  EMITTER BOND PAD CAPACITANCE
QINT    75      20      85      Q415    
.ENDS

.MODEL  Q415    NPN (BF=100, BR=2.5, IS=4.2E-16, VA=20, TF=12PS,
+               CJE=6E-13, VJE=1.01, MJE=0.6, PTF=25, XTB=1.818,
+               VTF=6, ITF=7.6E-2, IKF=3.4E-2, XTF=4, NF=1.03, ISE=1.3E-12,
+               NE=2.5, RB=11.57, RE=0.4, RC=18.03, CJC=2.5E-13, CJS=2.3E-13,
+               XCJC=0.20, PS=0.8, MS=0.5, PC=0.76, MC=0.53) 
To complete the transistor model, the above die model must be combined with one of the following package models.

AT-41511
pkg dwg
package 11 model
AT-41533
pkg dwg
package 33 model
AT-41586
pkg dwg
package 86 model


AT-420 Model

[ top ]
SPICE model

** DIE MODEL (excludes bond wires)
.SUBCKT AT420   75      20      85
CCB     20      60      .034PF
DCD1    20      60      DMOD    783
RRB1    20      25      0.7     TC=0.8E-3
DCD2    25      60      DMOD    972
RRB2    25      30      2.2     TC=1.2E-3
DCD3    30      60      DMOD    486
RRB3    30      35      1.9     TC=1.8E-3
RRC     60      75      5       TC=0.6E-3
RRE     80      85      .17     TC=0.6E-3
CCE     60      85      .034PF
QINT    60      35      80      QDIS     600
.ENDS

.MODEL  DMOD    D(IS=1E-25, CJO=2.45E-16, VJ=.76, M=.53, BV=45, IBV=1E-9)
.MODEL  QDIS    NPN (BF=90, BR=2.5, IS=1.7E-18, VA=20, TF=12PS,
+               CJE=2.4E-15, VJE=1.01, MJE=0.6, PTF=25, XTB=1.818,
+               VTF=6, ITF=3E-4, IKF=1.3E-4, XTF=4, NF=1.03, ISE=5E-15,
+               NE=2.5)
To complete the transistor model, the above die model must be combined with one of the following package models.

AT-42000
pkg dwg
package 00 model
AT-42010
pkg dwg
package 10 model
AT-42035
pkg dwg
package 35 model
AT-42070
pkg dwg
package 70 model
AT-42085
pkg dwg
package 85 model
AT-42086
pkg dwg
package 86 model


AT-640 Model

[ top ]
SPICE model

** DIE MODEL (excludes bond wires)
.SUBCKT AT640   75      20      85
QINT    75      20      85      Q640     
.ENDS

.MODEL  Q640    NPN (BF=100, BR=2.5, IS=2E-15, VA=20, TF=12PS, 
+               CJE=2.9E-12, VJE=1.01, MJE=0.6, PTF=25, XTB=1.818,
+               VTF=6, ITF=3.6E-1, IKF=1.6E-1, XTF=4, NF=1.03, ISE=6E-12,
+               NE=2.5, RB=2.83, RE=0.8, RC=33.95, CJC=1.6E-12, CJS=1.1E-12,
+               XCJC=0.15, PS=0.8, MS=0.5, PC=0.76, MC=0.53)
To complete the transistor model, the above die model must be combined with one of the following package models.

AT-64020
pkg dwg
package 20 model
AT-64023
pkg dwg
package 23 model

 


HBFP-0405 Model

[ top ]
SPICE model

* PSPICE MODEL for HBFP-0405 in SOT343

.SUBCKT HBFP0405   60      20      40
LL1     20      25      .22NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T1
C1T1    25      0       .08PF
LT1     25      30      .20NH
C2T1    30      0       .05PF
*
LLB     30      35      .70NH
CCEB    30      50      .04PF
LL2     40      45      .15NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T2
C1T2    45      0       .04PF
LT2     45      50      .10NH
C2T2    50      0       .10PF
*
LLE     50      55      .20NH
CCEC    50      70      .01PF
LL3     60      65      .20NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T3
C1T3    65      0       .144PF
LT3     65      70      .50NH
C2T3    70      0       .10PF
*
LLC	70	75	.70PF	
CCBC    30      70      .05PF
* CALL DIE MODEL
XDIE    75      35      55      H0405
.ENDS

.SUBCKT H0405   75      20      85
RBX 	20	130	3.74196
RCX	140 	75    	6.5915
RE	150 	85	1.565       
RSE	160	85	1
CCOX 	20     	140    	17.213E-15
CEOX 	130    	85     	6.227E-15
DBC	20	140	DMOD1
DBE	130	150	DMOD2
DCS	160	140	DMOD3
QINT  	140    	130	150	160	Q405     
.ENDS

.MODEL  DMOD1   D(IS=1.40507E-17,CJO=2.393E-14,VJ=.729,M=.44,TNOM=21,N=1,FC=0.8)
.MODEL  DMOD2   D(IS=1E-24,CJO=2.593E-14,VJ=.8971,M=.2292,TNOM=21,N=1.0029,FC=0.8)
.MODEL  DMOD3   D(IS=1E-24,CJO=8.974E-14,VJ=0.6,M=0.42 ,RS=2.17347E2,FC=0.8TNOM=21)

.MODEL  Q405    NPN (BF=1E6, IS=4.4746E-18,  VA=44,
     +    BR=1,     ME=0.5063,     NF=1,    PTF=22,
     +    TF=5.3706E-12,    CJE= 7.474248E-14,   XTF=20,     IK=1.4737E-01,
     +    PE=0.9907,    ISE=7.094E-20,     NE=1.006,    VTF=0.8,
     +    XTB=0.7,    ITF=2.21805486E-1,  RB=9.30144818,
     +    CJC=2.7056E-14,  XCJC=0.439790997,
     +    PC=0.6775,     MC=0.3319,  FC=0.8,  IKR=1.1E-2, NC=2, VAR=3.37,
     +    NR=1.005, TR=4E-9, TNOM=21, IRB=3.029562E-6, RBM=0.1, XTI=3
     +    EG=1.17)

* Note: high beta value compensates for current leakage through DBE	 

HBFP-0420 Model

[ top ]
SPICE model

* PSPICE MODEL for HBFP-0420 in SOT343

.SUBCKT HBFP0420   60      20      40
LL1     20      25      .22NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T1
C1T1    25      0       .08PF
LT1     25      30      .20NH
C2T1    30      0       .05PF
*
LLB     30      35      .70NH
CCEB    30      50      .04PF
LL2     40      45      .15NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T2
C1T2    45      0       .04PF
LT2     45      50      .10NH
C2T2    50      0       .10PF
*
LLE     50      55      .20NH
CCEC    50      70      .01PF
LL3     60      65      .20NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T3
C1T3    65      0       .144PF
LT3     65      70      .50NH
C2T3    70      0       .10PF
*
LLC	70	75	.70PF	
CCBC    30      70      .05PF
* CALL DIE MODEL
XDIE    75      35      55      H0420
.ENDS

.SUBCKT H0420   75      20      85	
RBX 	20	130	3.74196
RCX	140 	75    	6.5915
RE	150 	85	1.565       
RSE	160	85	1
CCOX 	20     	140    	17.213E-15
CEOX 	130    	85     	6.227E-15
DBC	20	140	DMOD1 3
DBE	130	150	DMOD2 3
DCS	160	140	DMOD3 3
QINT  	140    	130	150	160	Q405 3   
.ENDS

.MODEL  DMOD1   D(IS=1.40507E-17, CJO=2.393E-14,
+               VJ=.729, M=.44, TNOM=21, N=1, FC=0.8)
.MODEL  DMOD2   D(IS=1E-24, CJO=2.593E-14, VJ=.8971,
+               M=.2292, TNOM=21, N=1.0029, FC=0.8)
.MODEL  DMOD3   D(IS=1E-24, CJO=8.974E-14, VJ=0.6,
+               M=0.42, RS=2.17347E2, FC=0.8, TNOM=21)

.MODEL  Q405    NPN (BF=1E6, IS=4.4746E-18, VA=44,
     +    BR=1,ME=0.5063, NF=1, PTF=22, TF=5.3706E-12,
     +    CJE= 7.474248E-14, XTF=20, IK=1.4737E-01,
     +    PE=0.9907, ISE=7.094E-20, NE=1.006, VTF=0.8,
     +    XTB=0.7, ITF=2.21805486E-1, RB=9.30144818,
     +    CJC=2.7056E-14, XCJC=0.439790997,
     +    PC=0.6775, MC=0.3319, FC=0.8, IKR=1.1E-2, NC=2, VAR=3.37,
     +    NR=1.005, TR=4E-9, TNOM=21, IRB=3.029562E-6, RBM=0.1, XTI=3
     +    EG=1.17)
	 
* Note: high beta value compensates for current leakage through DBE	 


HBFP-0450 Model

[ top ]
SPICE model

.SUBCKT HBFP0450   60      20      40
LL1     20      25      .22NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T1
C1T1    25      0       .08PF
LT1     25      30      .20NH
C2T1    30      0       .05PF
*
LLB     30      35      .70NH
CCEB    30      50      .04PF
LL2     40      45      .15NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T2
C1T2    45      0       .04PF
LT2     45      50      .10NH
C2T2    50      0       .10PF
*
LLE     50      55      .20NH
CCEC    50      70      .01PF
LL3     60      65      .20NH
* PI NETWORK TO SIMULATE TRANSMISSION LINE T3
C1T3    65      0       .144PF
LT3     65      70      .50NH
C2T3    70      0       .10PF
*
LLC	70	75	.70PF	
CCBC    30      70      .05PF
* CALL DIE MODEL
XDIE    75      35      55      HP0450
.ENDS

.SUBCKT HP0450   75      20      85
RBX 	20	130	0.20995
RCX	140 	75    	0.4
RE	150 	84	0.1565       
RSE	160	85	1
RBAL	84	85	1.4
CCOX 	20     	140    	0.24 E-12
CEOX 	130    	84     	6.227E-14
DBC	20	140	DMOD1
DBE	130	150	DMOD2
DCS	160	140	DMOD3
QINT  	140    	130	150	160	Q450     
.ENDS

.MODEL  DMOD1   D(IS=1.40507E-17, CJO=2.393E-14,
+               VJ=.729, M=.44, TNOM=21, N=1, FC=0.8)
.MODEL  DMOD2   D(IS=1E-24, CJO=2.593E-14, VJ=.8971,
+               M=.2292, TNOM=21, N=1.0029, FC=0.8)
.MODEL  DMOD3   D(IS=1E-24, CJO=4.6443E-13, VJ=0.6,
+               M=0.42, RS=1.5804E2, FC=0.8, TNOM=21)

.MODEL  Q450    NPN (BF=1E6, IS=3.01E-17, VA=44, BR=1, 
     +    ME=0.5063, NF=1, PTF=22, TF=5.3706E-12, 
     +    CJE= 9.48E-14, XTF=20, IK=1.4737E-01, PE=0.9907, 
     +    ISE=5E-19, NE=1.006, VTF=0.8, XTB=0.7, 
     +    ITF=2.21805486, RB=9.30144818E-1, CJC=1.87E-14, 
     +    XCJC=0.439790997, PC=0.6775, MC=0.3319, FC=0.8, 
     +    IKR=1.1E-1, NC=2, VAR=30.37, NR=1.005, TR=4E-9, 
     +    TNOM=21, IRB=3.029562E-5, RBM=0.01, XTI=3, EG=1.17)

* Note: high beta value compensates for current leakage through DBE	 

 
Privacy Statement Terms of Use

this page last updated: 1 October 1999